This track rocketed to the #1 chart at soundclick.com and it also received great feedback on facebook. It is, however, a very different style compared to most other Imphenzia tracks released in the past.

The track, the feedback, and some recent expansion pack purchases for Nexus got me inspired to create more music.

Merry Christmas everyone =)

Maybe the simplest way to start off is to demonstrate how the scripts work with this video:

(Watch in HD at YouTube for better readability)

Click HERE TO DOWNLOAD the zip file containing the scripts.

Create_watermark.vbs Explained

This is a VBScript that will loop through a directory full of WAV audio files and mix them with watermark audio files. The script uses the free application Sound eXchange (SoX) to achieve this.

The script is also designed to take the duration of the audio file to be watermarked and apply a watermark with a suitable frequency.

Shorter audio files will be watermarked frequently and longer audio files will have less frequent watermarks to make it less annoying.

You can customize the watermark files to contain anything you want. If you want to change the name or format of them you’ll have to modify the script appropriately.

You can download the entire script package and demo files at the top of this post, but if you wish to have a look at the script itself, here it is:

' #############################################################################
'  IMPHENZIA SOUNDTRACK WATERMARKING SCRIPT    http://soundtrack.imphenzia.com
' #############################################################################

' ## DESCRIPTION ##############################################################

'   This VB script uses Sound eXchange (SoX) (http://sox.sourceforge.net) to
'   create watermarked WAV files.

'   Based on the duration of the WAV files you wish to watermark, the script
'   will select a suitable frequency of the watermark. By default the following
'   logic is applied:
'     0-5 second music file: watermark occurs every 2.5 seconds
'     5-15 second music file: watermark occurs every 5 seconds
'     15-30 second music file: watermark occurs every 10 seconds
'     30-1200 second music file: watermark occurs every 30 seconds
'     > 20 minutes files are not supported - change the script if necessary.

' ## INSTRUCTIONS #############################################################

'   1. Put your original WAV files that you wish to watermarked in the
'      subfolder "input-wav-originals"

'   2. Execute this script and it will create watermarked WAV files in the
'      subfolder "output-wav-watermarked"

' ## CHANGING THE WATERMARK ###################################################

'   The default watermark says the word "preview" at different intervals
'   depending on the duration of the WAV file. You can change the watermark
'   audio files but I recommend that you keep the name and ogg format of the
'   watermark files so you don't have to modify the script.

'   To change the watermark, replace the audio in the watermark files. Use
'   trial and error to find a suitable volume (I recommend peaks at around
'   -8 dB) and frequency of the watermark.

' ## LICENSE ##################################################################
'   You're free to use this script and the watermark OGG files free of charge.
'   If this script saves you a lot of time, a donation to paypal@imphenzia.com
'   is very welcome =)

'   SoX is a free application available at the URL in the description. This
'   script is very dependent on the exact output SoX generates to read
'   information so a version of SoX is included in the archive.

'   (You may not sell the script or any of the files)

Dim source_folder, destination_folder
Dim watermark_folder, watermark_file, log_filename

' ## CUSTOMIZABLE VARIABLES ###################################################
source_folder =      "input-wav-originals"
destination_folder = "output-wav-watermarked"
watermark_folder =   "input-watermarks"
log_filename =       "watermark-log.txt" ' Filename for log file (overwritten)
use_volume =         true                ' Watermark volume based on original

' You shouldn't need to edit any of the below script
' -----------------------------------------------------------------------------

Dim wshshell, filesys, folder, files_collection, filecount, filename
Dim outputfile, logoutput, duration, volume, volumedecimal, n

' ## Create Filesystem Objects
Set wshshell = WScript.CreateObject("WScript.Shell")
Set filesys = CreateObject("Scripting.FileSystemObject")
Set folder = filesys.GetFolder(source_folder & "\.")
Set files_collection = folder.Files
Set logoutput = filesys.OpenTextFile(log_filename, 2, True)

' ## Ensure that the output directory exists, if not then create it
if not filesys.FolderExists( destination_folder ) then _
  filesys.CreateFolder destination_folder

' ## Create header in log file
logoutput.WriteLine("Source File, Source Duration, Watermark, " & _
                    "Source Amplitude, Watermark Amplitude")

' ## Loop through all original wav files
filecount = files_collection.Count
for each file in files_collection
  filename = file.name
  if lcase(right(filename,4))=".wav" then

  ' ## If a watermarked version does not exists, create one
  if not filesys.FileExists( destination_folder & "\" & filename ) then

    ' ## Select appropriate watermarked file based on duration of source file
    duration = CLng(runCMD("sox --info -s """ & _
       source_folder & "\" & filename & """"))

    if duration <= 220500 then _
       watermark_file = watermark_folder & "\preview-0-5sec.ogg"
    if duration > 220500 and duration <= 661500 then _
       watermark_file = watermark_folder & "\preview-5-15sec.ogg"
    if duration > 661500 and duration <= 1323000 then _
       watermark_file = watermark_folder & "\preview-15-30sec.ogg"
    if duration > 1323000 then _
       watermark_file = watermark_folder & "\preview-30-1200sec.ogg"

    ' ## If volume is used, set volume based on amplitude of source wav file
    if use_volume then
      volume = runCMDAlt("sox """ & source_folder & "\" & filename & _
         """ -n stat")
      volume = mid(volume,123,8)
      volumedecimal = CDbl(replace(volume, ".", ","))
    else
      volumedecimal = 1.0
    end if

    ' ## Mix source wav file and watermark file to create a watermarked file
    wshshell.Run "sox -m  -v 1 """ & source_folder & "\" & filename & _
       """ -v " & replace((volumedecimal*volumedecimal),",",".") & _
       " """ & watermark_file & """ """ & destination_folder & _
       "\" & filename & """ trim 0s " & duration & "s",0,true

    ' ## Write the action to log file
    logoutput.WriteLine(source_folder & "\" & filename & "," & _
       watermark_file & "," & replace((CDbl(duration)/44100),",",".") & "," & _
       volume & "," & replace((volumedecimal*volumedecimal),",","."))

    n=n+1
    end if
  end if
next

if n=0 then
  wscript.echo "No Files Created " & vbCrLf & _
               "If watermarked files already exist they are not recreated"
else
  wscript.echo "Done! " & vbCrLf & n & " Watermarked File(s) Created "
end if

' Supporting function to capture the output of command line
function runCMD(strRunCmd)
  Set objExec = wshshell.Exec(strRunCmd)
  strOut = ""
  Do While Not objExec.StdOut.AtEndOfStream
    strOut = strOut & objExec.StdOut.ReadLine()
  Loop
  runCMD = strOut
End Function

' Supporting function to capture error output (workaround)
Function runCMDAlt(strRunCmd)
  Set objExec = wshshell.Exec(strRunCmd)
  strOut = ""
  strOut = objExec.StdErr.ReadAll()
  runCMDAlt = strOut
End Function

Encode_files.vbs Explained

This is a script that will loop through two directories, one full of original WAV audio/music files and one full of watermarked WAV files (if you previously ran the Create_watermarks.vbs script). As the script loops through all the available WAV files it will encode them into MP3 and OGG files and also update the meta tags containing information such as title, artist, publisher, copyright info, comments, URL, etc.

The script is designed so that you can enter meta tags and customize bit rate that you wish to encode your files with. Once you’ve got this running you can quickly re-encode your files into any bitrate or modify the meta tags without having to do it all manually.

You can download the entire script package and demo files at the top of this post, but if you wish to have a look at the script itself, here it is:

' #############################################################################
'  IMPHENZIA SOUNDTRACK ENCODING SCRIPT        http://soundtrack.imphenzia.com
' #############################################################################
'  Version: 1.0

' ## DESCRIPTION ##############################################################

'   This scripts encodes the wav files in the folder "input-wav-originals" and
'   "output-wav-watermarked" into MP3 and OGG files.

'   The script also creates meta tags for the MP3 and OGG files based on the
'   source file name and additional customizable in this script.

'   You can set the bitrate of the MP3 and OGG files in this script as well.

' ## INSTRUCTIONS #############################################################

'   1. Ensure that the WAV files in the "input-wav-originals" folder and the
'      "output-wav-watermarked" folders contain files named according to the
'      following naming standard:
'        Arist Name_Song Name_Music Genre_Year
'      Example:
'        Imphenzia Soundtrack_Fog of War (Main Part Loop)_Orchestral_2011.wav

'   2. Customize the encoding bitrates for the original and watermarked MP3
'      and OGG files (see CUSTOMIZABLE ENCODING BITRATES)

'   3. Customize the MP3 and OGG meta tags (see CUSTOMIZABLE MP3 and OGG TAGS)

'   4. Double click on the script to begin the encoding process. The script
'      will create MP3 and OGG files in the appropriately named output folders.

' ## LICENSE ##################################################################

'   You're free to use this script and the watermark OGG files free of charge.
'   If this script saves you a lot of time, a donation to paypal@imphenzia.com
'   is very welcome =)

'   This script uses the following freeware and/or open source applications:
'   lame.exe - http://www.mp3dev.org
'   metamp3.exe - http://www.hydrogenaudio.org/forums/index.php?showtopic=49751
'   oggenc.exe - http://www.rarewares.org/ogg-oggenc.php
'   tag.exe - http://wiki.hydrogenaudio.org/index.php?title=Tag_(tagger)

'   (You may not sell the script or any of the files)

Dim source_folder, source_watermarked_folder
Dim destination_mp3_original, destination_mp3_watermarked
Dim destination_ogg_original, destination_ogg_watermarked
Dim mp3_original_bitrate, mp3_watermarked_bitrate
Dim ogg_original_bitrate, ogg_watermarked_bitrate
Dim tag_encoder_name, tag_publisher_name, tag_copyright_name, tag_url
Dim tag_composer_name, tag_comment, tag_album, tag_watermarked_prefix

' ## CUSTOMIZABLE FOLDERS #####################################################
source_folder =               "input-wav-originals"
source_watermarked_folder =   "output-wav-watermarked"
destination_mp3_original =    "output-mp3-original"
destination_mp3_watermarked = "output-mp3-watermarked"
destination_ogg_original =    "output-ogg-original"
destination_ogg_watermarked = "output-ogg-watermarked"

' ## CUSTOMIZABLE ENCODING BITRATES ###########################################
mp3_original_bitrate =    "160"  ' Bitrate in kbps
mp3_watermarked_bitrate = "96"   ' Bitrate in kbps
ogg_original_bitrate =    "128"  ' Bitrate in kbps
ogg_watermarked_bitrate = "64"   ' Bitrate in kbps

' ## CUSTOMIZABLE MP3 and OGG TAGS#############################################
tag_encoder_name =   "ENCODER NAME HERE"
tag_publisher_name = "PUBLISHER NAME HERE"
tag_copyright_name = "COPYRIGHT HOLDER NAME HERE"
tag_url =            "http://YOUR URL HERE"
tag_composer_name =  "COMPOSER NAME HERE"
tag_comment =        "Encoded using script by http://soundtrack.imphenzia.com"
tag_album =          "TEXT FOR ALBUM FIELD HERE"
tag_watermarked_prefix = "Preview: "

' You shouldn't need to edit any of the below script
' -----------------------------------------------------------------------------

' Ensure that cscript is executed instead of wscript - otherwise status
' messages will appear in popups instead of console window.

If LCase(Right(Wscript.FullName, 11)) = "wscript.exe" Then
    strPath = Wscript.ScriptFullName
    strCommand = "%comspec% /k cscript  """ & strPath & """"
    Set objShell = CreateObject("Wscript.Shell")
    objShell.Run(strCommand), 1, True
    Wscript.Quit
End If

Dim wshshell, filesys, folder, files_collection, filecount, filename
Dim mp3counter, oggcounter, outputfile
Dim tag_artist, tag_title, tag_genre, tag_year
oggcounter = 0
mp3counter = 0

wscript.echo "Begin encoding process."

Set wshshell = WScript.CreateObject("WScript.Shell")
Set filesys = CreateObject("Scripting.FileSystemObject")

' ## Ensure that the output directories exists, if not then create them
if not filesys.FolderExists( destination_mp3_original ) then _
  filesys.CreateFolder destination_mp3_original
if not filesys.FolderExists( destination_ogg_original ) then _
  filesys.CreateFolder destination_ogg_original
if not filesys.FolderExists( destination_mp3_watermarked ) then _
  filesys.CreateFolder destination_mp3_watermarked
if not filesys.FolderExists( destination_ogg_watermarked ) then _
  filesys.CreateFolder destination_ogg_watermarked

' ## Encode Original (non-watermarked) files ##################################
Set folder = filesys.GetFolder(source_folder & "\.")
Set files_collection = folder.Files
filecount = files_collection.Count

for each file in files_collection
  ' ## Only process WAV files
  filename = file.name
  if lcase(right(filename,4))=".wav" then

    ' ## Set tags based on the filename
    ' ## Source File Name Format: Artist Name_Song Name_Music Genre_Year
    tag_artist = GetParam(filename,0)
    tag_title = GetParam(filename,1)
    tag_genre = GetParam(filename,2)
    tag_year = GetParam(filename,3)

    ' ## Create web friendly name for output file (artist-name-song-name)
    outputfile = WebFriendlyName(GetParam(filename,0) & " - " & _
                                 GetParam(filename,1) ,0,0)

    ' ## MP3 Encoding ---------------------------------------------------------
    ' ## Create option string for MP3 meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " --user-url " & """" & tag_url & """"
    optstr = optstr & " --frame TCOM:" & """" & tag_composer_name & """"
    optstr = optstr & " --frame TENC:" & """" & tag_encoder_name & """"
    optstr = optstr & " --frame TPUB:" & """" & tag_publisher_name & """"
    optstr = optstr & " --frame TCOP:" & """" & tag_copyright_name & """"

    ' ## Only encode the MP3 file if it doesn't already exist
    if not filesys.FileExists( destination_mp3_original & "\" & _
                               outputfile & ".mp3" ) then

      wscript.echo "Encoding Original mp3 with a bitrate of " & _
                    mp3_original_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".mp3" & vbCrLf

      ' ## Use Lame to encode the mp3 file
      wshshell.Run "lame.exe -b " & mp3_original_bitrate & _
                   " -c """ & source_folder & "\" & filename & """ " & _
                   """" & destination_mp3_original & "\" & outputfile & _
                   ".mp3""",0,true

      ' ## Use Metamp3 to create the mp3 tag
      wshshell.Run "metamp3.exe " & optstr & " """ & _
                   destination_mp3_original & "\" & outputfile & _
                   ".mp3""",0,true
      mp3counter = mp3counter + 1

    end if

    ' ## OGG Encoding ---------------------------------------------------------
    ' ## Create option string for OGG meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " -t URL=" & """" & tag_url & """"
    optstr = optstr & " -t COMPOSER=" & """" & tag_composer_name & """"
    optstr = optstr & " -t PUBLISHER=" & """" & tag_publisher_name & """"
    optstr = optstr & " -t COPYRIGHT=" & """" & tag_copyright_name & """"

    ' ## Only encode the OGG file if it doesn't already exist
    if not filesys.FileExists( destination_ogg_original & "\" &_
                               outputfile & ".ogg" ) then

      wscript.echo "Encoding Original ogg with a bitrate of " & _
                    ogg_original_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".ogg" & vbCrLf

      ' ## Use Oggenc to encode the ogg file
      wshshell.Run "oggenc.exe -b " & ogg_original_bitrate & _
                   " --output=""" & destination_ogg_original & "\" & _
                   outputfile & ".ogg"" """ & source_folder & "\" & _
                   filename & """",0,true

      ' ## Use Tag to create the ogg tag
      wshshell.Run "Tag.exe " & optstr & " """ & destination_ogg_original & _
                   "\" & outputfile & ".ogg""",0,true

      oggcounter = oggcounter + 1
    end if
  end if
next

' ## Encode Watermarked files #################################################
Set folder = filesys.GetFolder(source_watermarked_folder & "\.")
Set files_collection = folder.Files
filecount = files_collection.Count

for each file in files_collection
  ' ## Only process WAV files
  filename = file.name
  if lcase(right(filename,4))=".wav" then

    ' ## Set tags based on the filename
    ' ## Source File Name Format: Artist Name_Song Name_Music Genre_Year
    tag_artist = GetParam(filename,0)
    tag_title = tag_watermarked_prefix & GetParam(filename,1)
    tag_genre = GetParam(filename,2)
    tag_year = GetParam(filename,3)

    ' ## Create web friendly name for output file (artist-name-song-name)
    outputfile = WebFriendlyName(GetParam(filename,0) & " - " & _
                                 GetParam(filename,1) ,0,0)

    ' ## MP3 Encoding ---------------------------------------------------------
    ' ## Create option string for MP3 meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " --user-url " & """" & tag_url & """"
    optstr = optstr & " --frame TCOM:" & """" & tag_composer_name & """"
    optstr = optstr & " --frame TENC:" & """" & tag_encoder_name & """"
    optstr = optstr & " --frame TPUB:" & """" & tag_publisher_name & """"
    optstr = optstr & " --frame TCOP:" & """" & tag_copyright_name & """"

    ' ## Only encode the MP3 file if it doesn't already exist
    if not filesys.FileExists( destination_mp3_watermarked & "\" & _
                               outputfile & ".mp3" ) then

      wscript.echo "Encoding Watermarked mp3 with a bitrate of " & _
                    mp3_watermarked_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".mp3" & vbCrLf

      ' ## Use Lame to encode the mp3 file
      wshshell.Run "lame.exe -b " & mp3_watermarked_bitrate & _
                   " -c """ & source_watermarked_folder & "\" & filename & """ " & _
                   """" & destination_mp3_watermarked & "\" & outputfile & _
                   ".mp3""",0,true

      ' ## Use Metamp3 to create the mp3 tag
      wshshell.Run "metamp3.exe " & optstr & " """ & _
                   destination_mp3_watermarked & "\" & outputfile & _
                   ".mp3""",0,true
      mp3counter = mp3counter + 1

    end if

    ' ## OGG Encoding ---------------------------------------------------------
    ' ## Create option string for OGG meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " -t URL=" & """" & tag_url & """"
    optstr = optstr & " -t COMPOSER=" & """" & tag_composer_name & """"
    optstr = optstr & " -t PUBLISHER=" & """" & tag_publisher_name & """"
    optstr = optstr & " -t COPYRIGHT=" & """" & tag_copyright_name & """"

    ' ## Only encode the OGG file if it doesn't already exist
    if not filesys.FileExists( destination_ogg_watermarked & "\" &_
                               outputfile & ".ogg" ) then

      wscript.echo "Encoding Watermarked ogg with a bitrate of " & _
                    ogg_watermarked_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".ogg" & vbCrLf

      ' ## Use Oggenc to encode the ogg file
      wshshell.Run "oggenc.exe -b " & ogg_watermarked_bitrate & _
                   " --output=""" & destination_ogg_watermarked & "\" & _
                   outputfile & ".ogg"" """ & source_watermarked_folder & _
                   "\" & filename & """",0,true

      ' ## Use Tag to create the ogg tag
      wshshell.Run "Tag.exe " & optstr & " """ & _
                   destination_ogg_watermarked & _
                   "\" & outputfile & ".ogg""",0,true

      oggcounter = oggcounter + 1
    end if
  end if
next

' ## Finished - echo how many files were encoded
if mp3counter + oggcounter = 0 then
  wscript.echo "No files were encoded."
  wscript.echo "If the output files already exist they are not overwritten."
  wscript.echo "Delete them first if you wish re-encode them."
else
  wscript.echo "Encoding script reporting that all is done!"
  wscript.echo mp3counter & " mp3 files and " & oggcounter & " ogg files encoded"
end if

' Supporting function that gets a parameter from a file name using the
' character _ as a delimiter
Function GetParam(thestring, theparam)
  dim returnstring, currentparam
  for i=1 to len(thestring)
    if mid(thestring,i,1) = "_" then
      currentparam=currentparam+1
    else
      if theparam = currentparam then
        returnstring=returnstring + mid(thestring,i,1)
      end if
    end if
  next
  if lcase(right(returnstring,4)) = ".wav" then _
    returnstring=left(returnstring,len(returnstring)-4)
  GetParam = trim(returnstring)
end function

' Ugly supporting function that washes the file name to a "web friendly" file
' name... I would use regexp for this but VBScript is quite limited by default.
Function WebFriendlyName(filename, prefixlength, extlength)
	WebFriendlyName  = lcase(filename)
	WebFriendlyName  = right(WebFriendlyName , len(WebFriendlyName )-prefixlength)
	WebFriendlyName  = left(WebFriendlyName , len(WebFriendlyName )-extlength)
	WebFriendlyName  = replace(WebFriendlyName , " - ", "-")
	WebFriendlyName  = replace(WebFriendlyName , "[", "")
	WebFriendlyName  = replace(WebFriendlyName , "]", "")
	WebFriendlyName  = replace(WebFriendlyName , "(", "")
	WebFriendlyName  = replace(WebFriendlyName , ")", "")
	WebFriendlyName  = replace(WebFriendlyName , ".", "")
	WebFriendlyName  = replace(WebFriendlyName , "    ", " ")
	WebFriendlyName  = replace(WebFriendlyName , "   ", " ")
	WebFriendlyName  = replace(WebFriendlyName , "  ", " ")
	WebFriendlyName  = replace(WebFriendlyName , " ", "-")
End Function

Does this save you a lot of time?

I’ve put hours and hours into creating these scripts and if you find them very useful and they save you a lot of time – please consider buying one of my digital albums at http://music.imphenzia.com/albums.html or make a donation to paypal@imphenzia.com =)

See it’s not that sharp

I’m switching to C Sharp (C#) from Javascript (JS) in Unity3D and it’s slowing me down at the moment. I’m switching because I kept being told that C# is so much better – but so far my experience is that you just have to write more code and find workarounds for stuff =) Still, I gather I’ll find use of C# knowledge so I’ll persevere. It’ll also help me from snarfing code because most code is Javascript and if I manually convert it to C# I can understand it better… and improve it?

The bottom line is that I haven’t managed to get very far today on my Space fighter project today. I’ve got my ship flying around with mouse and keyboard control, I can fire an animated blaster canon, and I found out the Dynamic collision detection in Unity can’t really be trusted. Oddly enough the bullets collides with obstacles all the time, perfectly, in the editor – but not in the compiled version? I decided not to troubleshoot it any further because I use fast moving bullets and from what I gather I should be using raycasting instead so that’s something I’ll look deeper into tomorrow.

I nearly bought Harmor

Harmor VST - doesn't like 64 bit hosts

No, not armor. Harmor is an awesome sounding additive / subtractive synthersizer VST instrument. I mate of mine told me about it today and I downloaded the demo just to find out it’s a 32bit VST instrument and I run Cubase 5.5.3 x64 (64 bit). Harmon crashes Cubase for me after only a few minutes of use, gah.

Well, before buying Harmon – I thought I’d contact Image-Line (developer of Harmon) and ask them about their plugin crashing in Cubase. Image-Line support have no contact details on their web page and they direct all technical inquiries to their technical support forum…. Well, their technical support forum only appears to be supporting “FL Studio” because after registering in their forum I found out I have no authorization to post any questions in their support forum (which is also titled “FL Technical Support”.)

I then found out that VST Bridge (the component that keeps crashing in Cubase when i use 32 bit plugins) is not to be trusted if I go by what forum users at Steinberg say. Instead there is a suggestion to either downgrade to 32bit Cubase (which I don’t want to do because I have 24 GB Ram for my orchestral libraries and 32 bit Cubase would allow me to use about 3 GB of that memory at best), or use JBridge (or Bitbridge that I never found anywhere.)

jBridge

I downloaded the demo version of JBridge and it took me a few launches of the installer to figure out what to do, but I found a simple step by step instruction and using that the installation worked great.

Harmor seems more stable using JBridge, but it’s not hassle free their either. Quite a few times during half an hour of use Cubase froze, the Harmor GUI turned white with nothing in it, but I found some features I could enable in JBridge that seems to have combated most of the issues. Just as I write this I get “IL Harmor.dll – Forcing auxhost termination due to an error. Dispatcher: 19; Audiomaster: 15″ – and IL Harmor turned bright white again. Now I got “Dispatcher opcode 19 failed (IL Harmor (demo)/1229483375).” -but wait – I saw something in the help for that…  I have to enabled “I am getting a dispatcher opcode 19 error message” – great, I love it when I know what’s happening.

Well, I’m not convinced JBrige will solve any stability issues – I just seem to get other types of stability issues.

Summary

Today

• I nearly bought the front brake disk and hand guard mount (but time ran out)
• I nearly bought the toilet seat (but time ran out)
• I nearly made some progress in Unity (but C# & buggy collision detection stopped  me)
• I nearly bought the Harmor  VST (but it’s 32bit and buggy)
• I nearly contacted Image-Line support (but you can’t)
• I nearly bought JBridge (but it just changes the bugs around)
• I nearly went to bed in time, but now it’s 3:12AM

This video takes a detailed look at all the sections that form the track – such as the intro, the build up, the breakdown, the culmination, and the outro. It also explains how various instruments are introduced and modified during various stages of the track.

I am, by no means, saying that this is how you must make trance music – it’s just at peek into how I arrange most of my tracks. When I started out making music in the 90s I found no tutorials like this and I’m hoping that this video can help some of you that are interested in making music.

Right then, here is the tutorial of how to arrange a trance song / track:

As usual, I use Cubase 5 and my trusted VST instruments Nexus2, VanGuard, and Sylenth1 – but this arrangement technique can be applied regardless of what software you use.

If this tutorial helps you out – I’d be happy to hear about it in the comments field =)

Good luck and happy music making!

Have a look at the tutorial

What’s in the video?

The video describes the following elements:

• Percussion (drums) – kick, closed hihat, open hihat, claps, cymbals
• First bassline (rapid 1/16 notes)
• Second bassline  (offbeat 1/8 notes)
• Cluster of 5 simultaneous leads for extreme atmosphere
• Two trance gates for an even fuller effect
• Pads for more euphoria
• And a classic trance piano with delay end reverb

First the video lets you listen to the end result. Then I solo each instrument and describe what notes were played. You can also see exactly which presets are used in Nexus2, VanGuard, and Sylenth1. All presets, more or less, use the default settings and the default delay / reverb effects. Filter cutoff frequency is altered on a few instruments to create that classic morphing or transforming sound commonly found in trance. No additional, external, or invisible effects are applied.

In this video tutorial I use Cubase 5 as a sequencer – but the technique can be applied to any sequencer and VST instruments.

Since this video focuses on a cropped out section of the track, I plan to make another video showing how the track is arranged in terms of introducing various instruments, the intro, the chorus, the breakdown, the outro, etc.

If you like this video and, of course, if you like my music – please consider supporting Imphenzia by buying one of my albums in the album section (or on iTunes and other digital stores) – you can also gain Full Access to all Imphenzia tracks for high quality 320kbps MP3 and lossless FLAC files.

Virtual Instruments (VSTi) used

• Groove Agent ONE (Cubase 5 drum machine)
• ReFX Nexus2
• ReFX VanGuard
• LennarDigital Sylenth1

Presets used

All the presets are available in the retail version of each VSTi without the need for any expansions. The exception is the percussion since I just use various percussion samples.

ReFX Nexus2

• Bass | BA Trancebass 19
• Bass | Lazy Bass
• Single Layer Leads | LD Detuned Lead 1
• Epic Pads | PD Floating Away (with Trance Gate “TG” effect enabled)
• Epic Pads | PD Tranceiver
• Piano | PN Trancepiano

I’ve recently discovered the Dubstep genre and even though there are a lot of the tracks of that genre that I don’t particularly like, there are quite a few I really DO like as well. As I mentioned in an earlier post it was “Scary Monsters and Nice Sprites” by Skrillex that got me interested and I really liked the structured randomness of stabs and the wobbly bass.

I suggest, while reading this post, that you listen to Nostalgia [Dub Chill Edit] =)

Yesterday after I dropped off my son at daycare I had the melody of Nostalgia in my head and I imagined what it would sound like with some wobbles and random stabs in that track. When I came home I launched Cubase and loaded the chill-out version of Nostalgia to play around a while with the idea.

A few hours later I had a decent draft going with a duration of about a minute. I had to stop for the time being to resume some everyday-normal-duties but around 9 PM the kids were a sleep, we had finished eating Thai food, and the Cubase project was loaded.

I couldn’t stop until the clock showed 03:30 AM but I happy with the result and I considered the edit to be ready for release. Since it’s an edit the production time was greatly reduced because in general all the melodies and midi data is already there, it just needs rearranging with the exception for the additional random stabs, a modified beat, the wobble bass, and some instrument substitution.

To get the wobble bass, by the way, I use Sylenth1 and set the Low Frequency Oscillator 1 (LFO) to sinus wave and that it should modify Cutoff Frequency A. I then use VST Automation (see my tutorial on VST Automation in Cubase) to alter the rate of the LFO to achieve the wobble effect.

2 hours of sleep anyone?

I released the preview on Soundcloud last night before heading off to bed at 04:15 AM. My son woke up again at 06:55 and I had to get up with him to drop him off at daycare again . 2 hours and 40 minutes of sleep – wohoo. Following some positive comments about the track on the Imphenzia Facebook page I then started the process of releasing the track on Imphenzia.com.

The process of releasing a track

To release a new track on Imphenzia.com there are a few things I have to do.

Unmastering the skill of Mastering

First thing is first and I have to master the track. Unfortunately my mastering skills are absolutely awful and close to non-existent. I spend about 2 minutes mastering the track because my ears can’t really pick out the difference when it comes to EQing, limiting, compression, and altering the dynamics.

To give Nostalgia the drive through audio wash I load the 32 bit floating point WAV file I rendered in Cubase. I then apply quick EQ to drop some of the deepest bass frequencies and increase the mid-range and treble because I think my tracks are usually quite bass heavy when down-mixed in Cubase. I then normalize the track. And finally I use the Volume Maximizer in Sound Forge to limit at -6dB and compress the loudness. I only have my Sennheiser PXC 450 headphones and a pair of Logitech Z4 speakers to listen to the mix so, again, I wouldn’t know how to tweak the mix either way so I just release it. If you are reading this in disgust, and you possess amazing mastering skills, please contact me and help me out =)

Encoding the mp3 and flac files

So the track is “mastered” and re-sampled down to a 16 bit WAV-file. I then use my VBScript to encode the 320kbps MP3 version and the lossless FLAC version. This is a simple and automated process now and the script also creates the necessary mp3-tags and metadata.

Artwork

When releasing a single, I just have to create a small track icon in 100×100 pixels and 70×70 pixels for my web site. Since it’s an edit of an existing track, I just modified the Nostalgia icon – took me about 5 minutes.

Uploading to Soundclick

I have all my tracks on a VIP-account on Soundclick.com because I use their web player for streaming audio to Imphenzia.com visitors. I used to need this because I didn’t have enough storage on my website to host all my music but nowadays I could in theory stream it from the .com-site but then I’d lose out on the exposure at Soundclick. I usually hover in the top 10 of their trance charts so it’s a valuable self-promoting greater good to continue to have my music there. So I upload the 320kbps Mp3-file to Soundclick, write a description, and I also upload the 100×100 resolution icon.

Uploading to Imphenzia.com

Then it was time to upload the MP3 and FLAC versions to imphenzia.com (I use FTP) and these are the tracks that Full Access contributing visitors can download. I also update the MP3 and FLAC zip archives that contain all Imphenzia releases to-date. So it’s a fairly hefty bunch of megabytes being uploaded at this stage. I also upload the 70×70 and 100×100 track icons.

Updating the database

The PHP code on impheniza.com retrieves information from a MySQL database and for every track release I have to fill in some information. This includes, name, release timestamp, keywords, description, story, equipment used, duration, unique identifiers, etc. It only takes about 5 minutes or so, not too bad.

Notifying everyone

The track is up, time to notify everyone. First I announce the release on Facebook and Twitter. Then I use my e-mailer script to send out a notification to all subscribers. Today the list contained 806 e-mail addresses but over 180 e-mails sent bounced due inactive e-mail addresses and people having reached their quota. I decided to tidy up the list today so it meant manually removing the 180+ e-mail addresses from the database.

Updating the RSS XML File

This is the final step of my release process. I update an XML file containing the RSS feed for imphenzia.com but admittedly  I haven’t done this yet so I’ll have to do that in a second. I’m not sure if anyone even uses my RSS-feed to be honest, but I’ll keep updating it for the time being.

Without attempting to make a “proper” dub step track I decided to boot up Cubase and this is what I got so far:
Nostalgia [Dub Chill Edit] – Work in progress by Imphenzia

I’ll continue this piece tonight and hopefully it’ll result in a 3-4 minute edit of the Nostalgia track to be added to a new edition of the maxi single.

I’d be curious to find out what you think of this so feel free to comment =)

• Bitcrusher (Short Loop and Long Loop) is a dirty distorted futuristic beat with attitude.
• Arm For Battle (Loop) is a heroic orchestral loop portraying hope and preparation in a battle scenario.

What else did I do today?

Even though I am on paternity leave things are quite hectic at the moment – but in a good way.  I drop my son off at daycare at 08:45 in the mornings and then I have some time to spare for my projects until 13:30 when I pick him up again. He is only spending short periods of time there still as he just started last week but it’s still a bit heartbreaking leaving him in the morning as he bursts into tears as I leave him. My wife is taking care of our new baby girl most of the time so I can spend the 4 hours on my projects most days. Today was an exception though, I had to spend 2 hours searching for my wallet (which I had apparently left behind at the daycare center) and another 2 hours cleaning my car…. so no time for my projects during the day today.

3DS Max and Unity

I’m also spending some time in 3DS Max learning some low polygon modelling. I am making a little space game so I can learn both 3DS Max and Unity3D properly because I plan to make the sequel to the yet unreleased game “Performa Cars” using Unity’s powerful 3D engine. I will still make the game very much 2D looking because my passion is top-down racing.

Motocross

My KXF 450

Our local motocross track is open on Wednesday evenings (as well as weekends) so today I spend 3 hours there practicing. I rid my Kawasaki KXF 450 (2008 model) and it went fairly well until blisters in my left palm put an end to the session. I’ll have to figure out a way to tape it up for the weekend. My goal is to ride twice a week all year around. In the winter I put on spiked ice tires and I actually prefer to ride in the winter because the grip is amazing… and I don’t overheat as much as I do in the summer =)

Modern Warfare 2

I also managed to squeeze in a two hour session of playing Modern Warfare 2 with a mate of mine tonight.

Plan for the coming weeks

My plan for Imphenzia Projects during the coming weeks include:

• Re-launch the Imphenzia Games web site with the new design (as Music and Soundtrack)
• Release Performa Cars (a.k.a. project Computer Touring Car Championship) as freeware
• Composing more music for release on Imphenzia Soundtrack
• Continue to learn low poly modelling and Unity3D development for future Imphenzia Games projects
• Keep this blog updated

Imphenzia aside, I also need to:

• Spend time with my family
• Practice motocross
• Keep fit (run 3 times a week)
• Buy another car… can’t fit the new double pram in the boot/trunk…
• Contact contractors for building plans… boring…

Now it’s time for bed at 01:53 – should have no problem sleeping.

Shifting Focus

The first half of this year I put a lot of effort into Imphenzia Music by rebuilding the entire web site from scratch, creating a new web shop, introducing Full Access feature, releasing new singles, releasing the Chillout album, introducing all my music to digital stores and Spotify. I also made the decision to allow full length streaming of ALL my tracks (previously high quality streaming was only allowing the first two minutes.) I’m not sure if that was the right thing to do because since then the number of Full Access users have dropped and now one person every other month opts for (the low end of) Full Access. I will keep things as they are, but I think the lack of interest in downloading my music is one of the reasons why my motivation has switched to Imphenzia Sountrack at the moment. Not to worry, it’ll shift back at some stage =)

There is a hole in my virtual studio

I’ve purchased quite a few great music products over the past few of years, and my current virtual studio consists of the following:

• Steinberg Cubase 5.5
• reFX Nexus2 with the following expansions:
• Psytrance
• Store n Forward
• Hollywood
• Omnicron 2 and 3
• ROM Extension
• reFX VanGuard with the following additional sound banks:
• Bigtone Electronic Garden, Silicon Frontiers Bank and Soundbank
• NextBeat Dance Basics Bank
• Revolution Soundbank 1, 2 and 3
• Synthation Bank
• Toxcity Bank
• Xenox Signature Bank 1 and 2
• LennarDigital Sylenth 1
• EastWest Quantum Leap Symphonic Orchestra Gold (33 GB sample library)
• EastWest Symphonic Choirs (39 GB sample library)
• EastWest Pianos Gold (50 GB sample library)
• Quantum Leap Goliath (41 GB sample library)
• Stormdrum 2 (13 GB sample library)
• Voices of Passion (8 GB sample library)
• Ministry of Rock (20 GB sample library

For Imphenzia Soundtrack, on the other hand, I am missing an instrument or library for soundscape textures, glitches, and futuristic grunge style sounds.

I’ve done some online searching today and I found Native Instruments Abysnth 5 which I think will fill this hole perfectly. Absynth comes with 1800 presets and a, what seems to be an amazing, morph feature that will allow the creation of totally unique sounds. I’ve been looking at the demo videos and listened to the sample tracks and all I have to do now is to decide whether I should by the boxed DVD version or the digital download version. If I get the digital version I’ll have it straight away but I’ve got boxed versions for Nexus, Cubase, and the Complete Composer’s edition (featuring all the large sample libraries) so it would be nice to have the cyan colored Abynth 5 box in that collection. Both the digital download and boxed version is €179 (including shipping) so I’m leaning towards the box after all. My PayPal account is missing $25 so I’ll wait to see if any non-exclusive licenses go so I can place the order.

Good hardware for the gigantic sample libraries

The only music hardware I use nowadays is my 88-key Roland FP-7 stage piano as master midi keyboard and to play improvisation to come up with new ideas. Some will find it amusing, but I use the Asus motherboard sound card. I down-mix all the audio without it ever touching the sound card so it serves no purpose to get another one. In fact, I’ve got a Creamware Pulsar 2 DSP sound card that I bought for £2000 – but it’s old now and they didn’t bother to release any Windows 7 drivers for it… But again, I don’t need it =)

If you found this post because you are looking for a computer with a lot of memory to run the EastWest libraries – I can confirm that my current computer handles it beautifully:

• Asus P6X58D-E Motherboard
• 24 GB RAM using 2 x Corsair 12GB (3 kit) DDR3 1600MHz/CL9/DOMINATOR
• Intel Core i7 3.06GHz Quad 8MB Cache Processor
• Corsair AX 850W PSU
• Crucial RealSSD 256GB (for the sound libraries, they consist of over 177’000 files)
• Corsair SSD Force Series 120GB (for Windows 7 x64 Ultimate

Signing off with a bombshell

To finish off I’ll take this opportunity to share s sample of an orchestral piece I started working on today. Enjoy!
Imphenzia Soundtrack work in progress “Arm for Battle Loop” by Imphenzia

While walking around in the garden with the “Computer Sweden” newspaper (August 12, 2011) I stumbled upon an article forcing me to whine more on this topic.

The Article…

…explains that the employees of Spotify are jackpot winners. The shares that Spotify offered to sell to its employees last year have increased in value from around $950’000 to $45’000’000. That is an increase of 4737% which is, of course, great news for the employees that purchased shares. I’m happy for them!

This share increase is, however, not what caught my attention. As I read on I find out that the shares rocketed in value following new investment funding injected into Spotify by Digital Sky Technologies and, Klein Perkins, and Accel.

Figures show that this year alone, investment companies have pumped in over $100’000’000 (that is $100 million) into Spotify.

At the same time the Spotify holding company, based in Luxembourg, declared a loss of $37 million in 2010 as a result of injecting funding into its own affiliates.

Golf ball on the peg – bring out the Bang-O-Matic driver

Now I’m no rocket scientist (but I do create sound effects for rocket thrusters.) but I’m going to allow myself to speculate…

A company costs money to run. You have plenty of expenses to cover for all sorts of things such as employees, research and development, IT infrastructure, procurement costs, office rental, and so forth. But seriously, $100 million have been injected in a company this year alone that, let’s face it, streams music to its users on the Internet. Sure, bandwidth costs a fair share and developing an audio player isn’t all together that complicated – it hardly justified such a high price tag.

Now Spotify generates their own income as well, from all its advertisements and premium subscribers. The number of premium, or at least paying, subscribers in July 2011 is estimated to 1.5 million out of the total number of 10 million users. This is money coming into Spotify beside the risk venture capital.

What’s at the bottom of the money grinder?

The article also describes that Spotify managed to “get rid” of a debt of $31 million by converting the debt to the affected shareholder(s) into additional shares.

Spotify is valued at over $1 billion as of August 2011. The employees that purchased their shares that are now worth $45 million leaves the remaining mystery shareholders with a share value of $6’550 million.

Independent and small artists, such as myself, kindly more or less donate our music to Spotify for them to add to their catalog. But the artists, who created the gold that Spotify is selling, get little reward for this.

My speculation is that the shareholders that own the remaining shares valued at $6.5 billion are to a large part the major record companies that so kindly offer their music to be streamed. The small amounts of royalties that are handed out “per play” is just a play for to the gallery. The BIG money to be made is by owning shares in Spotify. The major record labels that make millions through their shares also reward their top named artists, I presume, but I’m convinced that the majority is pocketed by the labels themselves.