Maybe the simplest way to start off is to demonstrate how the scripts work with this video:

(Watch in HD at YouTube for better readability)

Click HERE TO DOWNLOAD the zip file containing the scripts.

Create_watermark.vbs Explained

This is a VBScript that will loop through a directory full of WAV audio files and mix them with watermark audio files. The script uses the free application Sound eXchange (SoX) to achieve this.

The script is also designed to take the duration of the audio file to be watermarked and apply a watermark with a suitable frequency.

Shorter audio files will be watermarked frequently and longer audio files will have less frequent watermarks to make it less annoying.

You can customize the watermark files to contain anything you want. If you want to change the name or format of them you’ll have to modify the script appropriately.

You can download the entire script package and demo files at the top of this post, but if you wish to have a look at the script itself, here it is:

' #############################################################################
'  IMPHENZIA SOUNDTRACK WATERMARKING SCRIPT    http://soundtrack.imphenzia.com
' #############################################################################

' ## DESCRIPTION ##############################################################

'   This VB script uses Sound eXchange (SoX) (http://sox.sourceforge.net) to
'   create watermarked WAV files.

'   Based on the duration of the WAV files you wish to watermark, the script
'   will select a suitable frequency of the watermark. By default the following
'   logic is applied:
'     0-5 second music file: watermark occurs every 2.5 seconds
'     5-15 second music file: watermark occurs every 5 seconds
'     15-30 second music file: watermark occurs every 10 seconds
'     30-1200 second music file: watermark occurs every 30 seconds
'     > 20 minutes files are not supported - change the script if necessary.

' ## INSTRUCTIONS #############################################################

'   1. Put your original WAV files that you wish to watermarked in the
'      subfolder "input-wav-originals"

'   2. Execute this script and it will create watermarked WAV files in the
'      subfolder "output-wav-watermarked"

' ## CHANGING THE WATERMARK ###################################################

'   The default watermark says the word "preview" at different intervals
'   depending on the duration of the WAV file. You can change the watermark
'   audio files but I recommend that you keep the name and ogg format of the
'   watermark files so you don't have to modify the script.

'   To change the watermark, replace the audio in the watermark files. Use
'   trial and error to find a suitable volume (I recommend peaks at around
'   -8 dB) and frequency of the watermark.

' ## LICENSE ##################################################################
'   You're free to use this script and the watermark OGG files free of charge.
'   If this script saves you a lot of time, a donation to paypal@imphenzia.com
'   is very welcome =)

'   SoX is a free application available at the URL in the description. This
'   script is very dependent on the exact output SoX generates to read
'   information so a version of SoX is included in the archive.

'   (You may not sell the script or any of the files)

Dim source_folder, destination_folder
Dim watermark_folder, watermark_file, log_filename

' ## CUSTOMIZABLE VARIABLES ###################################################
source_folder =      "input-wav-originals"
destination_folder = "output-wav-watermarked"
watermark_folder =   "input-watermarks"
log_filename =       "watermark-log.txt" ' Filename for log file (overwritten)
use_volume =         true                ' Watermark volume based on original

' You shouldn't need to edit any of the below script
' -----------------------------------------------------------------------------

Dim wshshell, filesys, folder, files_collection, filecount, filename
Dim outputfile, logoutput, duration, volume, volumedecimal, n

' ## Create Filesystem Objects
Set wshshell = WScript.CreateObject("WScript.Shell")
Set filesys = CreateObject("Scripting.FileSystemObject")
Set folder = filesys.GetFolder(source_folder & "\.")
Set files_collection = folder.Files
Set logoutput = filesys.OpenTextFile(log_filename, 2, True)

' ## Ensure that the output directory exists, if not then create it
if not filesys.FolderExists( destination_folder ) then _
  filesys.CreateFolder destination_folder

' ## Create header in log file
logoutput.WriteLine("Source File, Source Duration, Watermark, " & _
                    "Source Amplitude, Watermark Amplitude")

' ## Loop through all original wav files
filecount = files_collection.Count
for each file in files_collection
  filename = file.name
  if lcase(right(filename,4))=".wav" then

  ' ## If a watermarked version does not exists, create one
  if not filesys.FileExists( destination_folder & "\" & filename ) then

    ' ## Select appropriate watermarked file based on duration of source file
    duration = CLng(runCMD("sox --info -s """ & _
       source_folder & "\" & filename & """"))

    if duration <= 220500 then _
       watermark_file = watermark_folder & "\preview-0-5sec.ogg"
    if duration > 220500 and duration <= 661500 then _
       watermark_file = watermark_folder & "\preview-5-15sec.ogg"
    if duration > 661500 and duration <= 1323000 then _
       watermark_file = watermark_folder & "\preview-15-30sec.ogg"
    if duration > 1323000 then _
       watermark_file = watermark_folder & "\preview-30-1200sec.ogg"

    ' ## If volume is used, set volume based on amplitude of source wav file
    if use_volume then
      volume = runCMDAlt("sox """ & source_folder & "\" & filename & _
         """ -n stat")
      volume = mid(volume,123,8)
      volumedecimal = CDbl(replace(volume, ".", ","))
    else
      volumedecimal = 1.0
    end if

    ' ## Mix source wav file and watermark file to create a watermarked file
    wshshell.Run "sox -m  -v 1 """ & source_folder & "\" & filename & _
       """ -v " & replace((volumedecimal*volumedecimal),",",".") & _
       " """ & watermark_file & """ """ & destination_folder & _
       "\" & filename & """ trim 0s " & duration & "s",0,true

    ' ## Write the action to log file
    logoutput.WriteLine(source_folder & "\" & filename & "," & _
       watermark_file & "," & replace((CDbl(duration)/44100),",",".") & "," & _
       volume & "," & replace((volumedecimal*volumedecimal),",","."))

    n=n+1
    end if
  end if
next

if n=0 then
  wscript.echo "No Files Created " & vbCrLf & _
               "If watermarked files already exist they are not recreated"
else
  wscript.echo "Done! " & vbCrLf & n & " Watermarked File(s) Created "
end if

' Supporting function to capture the output of command line
function runCMD(strRunCmd)
  Set objExec = wshshell.Exec(strRunCmd)
  strOut = ""
  Do While Not objExec.StdOut.AtEndOfStream
    strOut = strOut & objExec.StdOut.ReadLine()
  Loop
  runCMD = strOut
End Function

' Supporting function to capture error output (workaround)
Function runCMDAlt(strRunCmd)
  Set objExec = wshshell.Exec(strRunCmd)
  strOut = ""
  strOut = objExec.StdErr.ReadAll()
  runCMDAlt = strOut
End Function

Encode_files.vbs Explained

This is a script that will loop through two directories, one full of original WAV audio/music files and one full of watermarked WAV files (if you previously ran the Create_watermarks.vbs script). As the script loops through all the available WAV files it will encode them into MP3 and OGG files and also update the meta tags containing information such as title, artist, publisher, copyright info, comments, URL, etc.

The script is designed so that you can enter meta tags and customize bit rate that you wish to encode your files with. Once you’ve got this running you can quickly re-encode your files into any bitrate or modify the meta tags without having to do it all manually.

You can download the entire script package and demo files at the top of this post, but if you wish to have a look at the script itself, here it is:

' #############################################################################
'  IMPHENZIA SOUNDTRACK ENCODING SCRIPT        http://soundtrack.imphenzia.com
' #############################################################################
'  Version: 1.0

' ## DESCRIPTION ##############################################################

'   This scripts encodes the wav files in the folder "input-wav-originals" and
'   "output-wav-watermarked" into MP3 and OGG files.

'   The script also creates meta tags for the MP3 and OGG files based on the
'   source file name and additional customizable in this script.

'   You can set the bitrate of the MP3 and OGG files in this script as well.

' ## INSTRUCTIONS #############################################################

'   1. Ensure that the WAV files in the "input-wav-originals" folder and the
'      "output-wav-watermarked" folders contain files named according to the
'      following naming standard:
'        Arist Name_Song Name_Music Genre_Year
'      Example:
'        Imphenzia Soundtrack_Fog of War (Main Part Loop)_Orchestral_2011.wav

'   2. Customize the encoding bitrates for the original and watermarked MP3
'      and OGG files (see CUSTOMIZABLE ENCODING BITRATES)

'   3. Customize the MP3 and OGG meta tags (see CUSTOMIZABLE MP3 and OGG TAGS)

'   4. Double click on the script to begin the encoding process. The script
'      will create MP3 and OGG files in the appropriately named output folders.

' ## LICENSE ##################################################################

'   You're free to use this script and the watermark OGG files free of charge.
'   If this script saves you a lot of time, a donation to paypal@imphenzia.com
'   is very welcome =)

'   This script uses the following freeware and/or open source applications:
'   lame.exe - http://www.mp3dev.org
'   metamp3.exe - http://www.hydrogenaudio.org/forums/index.php?showtopic=49751
'   oggenc.exe - http://www.rarewares.org/ogg-oggenc.php
'   tag.exe - http://wiki.hydrogenaudio.org/index.php?title=Tag_(tagger)

'   (You may not sell the script or any of the files)

Dim source_folder, source_watermarked_folder
Dim destination_mp3_original, destination_mp3_watermarked
Dim destination_ogg_original, destination_ogg_watermarked
Dim mp3_original_bitrate, mp3_watermarked_bitrate
Dim ogg_original_bitrate, ogg_watermarked_bitrate
Dim tag_encoder_name, tag_publisher_name, tag_copyright_name, tag_url
Dim tag_composer_name, tag_comment, tag_album, tag_watermarked_prefix

' ## CUSTOMIZABLE FOLDERS #####################################################
source_folder =               "input-wav-originals"
source_watermarked_folder =   "output-wav-watermarked"
destination_mp3_original =    "output-mp3-original"
destination_mp3_watermarked = "output-mp3-watermarked"
destination_ogg_original =    "output-ogg-original"
destination_ogg_watermarked = "output-ogg-watermarked"

' ## CUSTOMIZABLE ENCODING BITRATES ###########################################
mp3_original_bitrate =    "160"  ' Bitrate in kbps
mp3_watermarked_bitrate = "96"   ' Bitrate in kbps
ogg_original_bitrate =    "128"  ' Bitrate in kbps
ogg_watermarked_bitrate = "64"   ' Bitrate in kbps

' ## CUSTOMIZABLE MP3 and OGG TAGS#############################################
tag_encoder_name =   "ENCODER NAME HERE"
tag_publisher_name = "PUBLISHER NAME HERE"
tag_copyright_name = "COPYRIGHT HOLDER NAME HERE"
tag_url =            "http://YOUR URL HERE"
tag_composer_name =  "COMPOSER NAME HERE"
tag_comment =        "Encoded using script by http://soundtrack.imphenzia.com"
tag_album =          "TEXT FOR ALBUM FIELD HERE"
tag_watermarked_prefix = "Preview: "

' You shouldn't need to edit any of the below script
' -----------------------------------------------------------------------------

' Ensure that cscript is executed instead of wscript - otherwise status
' messages will appear in popups instead of console window.

If LCase(Right(Wscript.FullName, 11)) = "wscript.exe" Then
    strPath = Wscript.ScriptFullName
    strCommand = "%comspec% /k cscript  """ & strPath & """"
    Set objShell = CreateObject("Wscript.Shell")
    objShell.Run(strCommand), 1, True
    Wscript.Quit
End If

Dim wshshell, filesys, folder, files_collection, filecount, filename
Dim mp3counter, oggcounter, outputfile
Dim tag_artist, tag_title, tag_genre, tag_year
oggcounter = 0
mp3counter = 0

wscript.echo "Begin encoding process."

Set wshshell = WScript.CreateObject("WScript.Shell")
Set filesys = CreateObject("Scripting.FileSystemObject")

' ## Ensure that the output directories exists, if not then create them
if not filesys.FolderExists( destination_mp3_original ) then _
  filesys.CreateFolder destination_mp3_original
if not filesys.FolderExists( destination_ogg_original ) then _
  filesys.CreateFolder destination_ogg_original
if not filesys.FolderExists( destination_mp3_watermarked ) then _
  filesys.CreateFolder destination_mp3_watermarked
if not filesys.FolderExists( destination_ogg_watermarked ) then _
  filesys.CreateFolder destination_ogg_watermarked

' ## Encode Original (non-watermarked) files ##################################
Set folder = filesys.GetFolder(source_folder & "\.")
Set files_collection = folder.Files
filecount = files_collection.Count

for each file in files_collection
  ' ## Only process WAV files
  filename = file.name
  if lcase(right(filename,4))=".wav" then

    ' ## Set tags based on the filename
    ' ## Source File Name Format: Artist Name_Song Name_Music Genre_Year
    tag_artist = GetParam(filename,0)
    tag_title = GetParam(filename,1)
    tag_genre = GetParam(filename,2)
    tag_year = GetParam(filename,3)

    ' ## Create web friendly name for output file (artist-name-song-name)
    outputfile = WebFriendlyName(GetParam(filename,0) & " - " & _
                                 GetParam(filename,1) ,0,0)

    ' ## MP3 Encoding ---------------------------------------------------------
    ' ## Create option string for MP3 meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " --user-url " & """" & tag_url & """"
    optstr = optstr & " --frame TCOM:" & """" & tag_composer_name & """"
    optstr = optstr & " --frame TENC:" & """" & tag_encoder_name & """"
    optstr = optstr & " --frame TPUB:" & """" & tag_publisher_name & """"
    optstr = optstr & " --frame TCOP:" & """" & tag_copyright_name & """"

    ' ## Only encode the MP3 file if it doesn't already exist
    if not filesys.FileExists( destination_mp3_original & "\" & _
                               outputfile & ".mp3" ) then

      wscript.echo "Encoding Original mp3 with a bitrate of " & _
                    mp3_original_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".mp3" & vbCrLf

      ' ## Use Lame to encode the mp3 file
      wshshell.Run "lame.exe -b " & mp3_original_bitrate & _
                   " -c """ & source_folder & "\" & filename & """ " & _
                   """" & destination_mp3_original & "\" & outputfile & _
                   ".mp3""",0,true

      ' ## Use Metamp3 to create the mp3 tag
      wshshell.Run "metamp3.exe " & optstr & " """ & _
                   destination_mp3_original & "\" & outputfile & _
                   ".mp3""",0,true
      mp3counter = mp3counter + 1

    end if

    ' ## OGG Encoding ---------------------------------------------------------
    ' ## Create option string for OGG meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " -t URL=" & """" & tag_url & """"
    optstr = optstr & " -t COMPOSER=" & """" & tag_composer_name & """"
    optstr = optstr & " -t PUBLISHER=" & """" & tag_publisher_name & """"
    optstr = optstr & " -t COPYRIGHT=" & """" & tag_copyright_name & """"

    ' ## Only encode the OGG file if it doesn't already exist
    if not filesys.FileExists( destination_ogg_original & "\" &_
                               outputfile & ".ogg" ) then

      wscript.echo "Encoding Original ogg with a bitrate of " & _
                    ogg_original_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".ogg" & vbCrLf

      ' ## Use Oggenc to encode the ogg file
      wshshell.Run "oggenc.exe -b " & ogg_original_bitrate & _
                   " --output=""" & destination_ogg_original & "\" & _
                   outputfile & ".ogg"" """ & source_folder & "\" & _
                   filename & """",0,true

      ' ## Use Tag to create the ogg tag
      wshshell.Run "Tag.exe " & optstr & " """ & destination_ogg_original & _
                   "\" & outputfile & ".ogg""",0,true

      oggcounter = oggcounter + 1
    end if
  end if
next

' ## Encode Watermarked files #################################################
Set folder = filesys.GetFolder(source_watermarked_folder & "\.")
Set files_collection = folder.Files
filecount = files_collection.Count

for each file in files_collection
  ' ## Only process WAV files
  filename = file.name
  if lcase(right(filename,4))=".wav" then

    ' ## Set tags based on the filename
    ' ## Source File Name Format: Artist Name_Song Name_Music Genre_Year
    tag_artist = GetParam(filename,0)
    tag_title = tag_watermarked_prefix & GetParam(filename,1)
    tag_genre = GetParam(filename,2)
    tag_year = GetParam(filename,3)

    ' ## Create web friendly name for output file (artist-name-song-name)
    outputfile = WebFriendlyName(GetParam(filename,0) & " - " & _
                                 GetParam(filename,1) ,0,0)

    ' ## MP3 Encoding ---------------------------------------------------------
    ' ## Create option string for MP3 meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " --user-url " & """" & tag_url & """"
    optstr = optstr & " --frame TCOM:" & """" & tag_composer_name & """"
    optstr = optstr & " --frame TENC:" & """" & tag_encoder_name & """"
    optstr = optstr & " --frame TPUB:" & """" & tag_publisher_name & """"
    optstr = optstr & " --frame TCOP:" & """" & tag_copyright_name & """"

    ' ## Only encode the MP3 file if it doesn't already exist
    if not filesys.FileExists( destination_mp3_watermarked & "\" & _
                               outputfile & ".mp3" ) then

      wscript.echo "Encoding Watermarked mp3 with a bitrate of " & _
                    mp3_watermarked_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".mp3" & vbCrLf

      ' ## Use Lame to encode the mp3 file
      wshshell.Run "lame.exe -b " & mp3_watermarked_bitrate & _
                   " -c """ & source_watermarked_folder & "\" & filename & """ " & _
                   """" & destination_mp3_watermarked & "\" & outputfile & _
                   ".mp3""",0,true

      ' ## Use Metamp3 to create the mp3 tag
      wshshell.Run "metamp3.exe " & optstr & " """ & _
                   destination_mp3_watermarked & "\" & outputfile & _
                   ".mp3""",0,true
      mp3counter = mp3counter + 1

    end if

    ' ## OGG Encoding ---------------------------------------------------------
    ' ## Create option string for OGG meta tags
    optstr = ""
    optstr = optstr & " --title " & """" & tag_title & """"
    optstr = optstr & " --artist " & """" & tag_artist & """"
    optstr = optstr & " --comment " & """" & tag_comment & """"
    optstr = optstr & " --genre " & """" & tag_genre & """"
    optstr = optstr & " --year " & """" & tag_year & """"
    optstr = optstr & " --album " & """" & tag_album & """"
    optstr = optstr & " -t URL=" & """" & tag_url & """"
    optstr = optstr & " -t COMPOSER=" & """" & tag_composer_name & """"
    optstr = optstr & " -t PUBLISHER=" & """" & tag_publisher_name & """"
    optstr = optstr & " -t COPYRIGHT=" & """" & tag_copyright_name & """"

    ' ## Only encode the OGG file if it doesn't already exist
    if not filesys.FileExists( destination_ogg_watermarked & "\" &_
                               outputfile & ".ogg" ) then

      wscript.echo "Encoding Watermarked ogg with a bitrate of " & _
                    ogg_watermarked_bitrate & "kbps: " & vbCrLf & _
                    " " & outputfile & ".ogg" & vbCrLf

      ' ## Use Oggenc to encode the ogg file
      wshshell.Run "oggenc.exe -b " & ogg_watermarked_bitrate & _
                   " --output=""" & destination_ogg_watermarked & "\" & _
                   outputfile & ".ogg"" """ & source_watermarked_folder & _
                   "\" & filename & """",0,true

      ' ## Use Tag to create the ogg tag
      wshshell.Run "Tag.exe " & optstr & " """ & _
                   destination_ogg_watermarked & _
                   "\" & outputfile & ".ogg""",0,true

      oggcounter = oggcounter + 1
    end if
  end if
next

' ## Finished - echo how many files were encoded
if mp3counter + oggcounter = 0 then
  wscript.echo "No files were encoded."
  wscript.echo "If the output files already exist they are not overwritten."
  wscript.echo "Delete them first if you wish re-encode them."
else
  wscript.echo "Encoding script reporting that all is done!"
  wscript.echo mp3counter & " mp3 files and " & oggcounter & " ogg files encoded"
end if

' Supporting function that gets a parameter from a file name using the
' character _ as a delimiter
Function GetParam(thestring, theparam)
  dim returnstring, currentparam
  for i=1 to len(thestring)
    if mid(thestring,i,1) = "_" then
      currentparam=currentparam+1
    else
      if theparam = currentparam then
        returnstring=returnstring + mid(thestring,i,1)
      end if
    end if
  next
  if lcase(right(returnstring,4)) = ".wav" then _
    returnstring=left(returnstring,len(returnstring)-4)
  GetParam = trim(returnstring)
end function

' Ugly supporting function that washes the file name to a "web friendly" file
' name... I would use regexp for this but VBScript is quite limited by default.
Function WebFriendlyName(filename, prefixlength, extlength)
	WebFriendlyName  = lcase(filename)
	WebFriendlyName  = right(WebFriendlyName , len(WebFriendlyName )-prefixlength)
	WebFriendlyName  = left(WebFriendlyName , len(WebFriendlyName )-extlength)
	WebFriendlyName  = replace(WebFriendlyName , " - ", "-")
	WebFriendlyName  = replace(WebFriendlyName , "[", "")
	WebFriendlyName  = replace(WebFriendlyName , "]", "")
	WebFriendlyName  = replace(WebFriendlyName , "(", "")
	WebFriendlyName  = replace(WebFriendlyName , ")", "")
	WebFriendlyName  = replace(WebFriendlyName , ".", "")
	WebFriendlyName  = replace(WebFriendlyName , "    ", " ")
	WebFriendlyName  = replace(WebFriendlyName , "   ", " ")
	WebFriendlyName  = replace(WebFriendlyName , "  ", " ")
	WebFriendlyName  = replace(WebFriendlyName , " ", "-")
End Function

Does this save you a lot of time?

I’ve put hours and hours into creating these scripts and if you find them very useful and they save you a lot of time – please consider buying one of my digital albums at http://music.imphenzia.com/albums.html or make a donation to paypal@imphenzia.com =)

Motocross practice at Uringe

Today I spent a few hours at Uringe, a great sand track south of Stockholm, where I tried to improve my motocross skills. It went fairly well with only one minor crash but plenty of fun. Bike collected some sand as you can see in the picture below – quite easy to clean with the pressure washer though….

Making Exlusive Music for Three Games

I’ve also recently had requests to create exclusive music for three different games. Two games for the mobile platform (Android + iPhone) and one game is aimed at computers and consoles.

Quite exciting because the music needed is of very different genres and it’s a lot of fun to let the creativity take over and see where it leads.

Astrofighter.Net

As for Astrofighter.Net I’ve managed to make slight progress here as well. I’ve imported the low poly ship versions into Unity and I’m currently placing all the thruster and weapon mount points. Next will be texture mapping the ships and adding script code for the remaining weapon types.

As an artist I released my new track “Nostalgia [Dub Chill Edit]” yesterday. Today I found the time to create seamless loops and music hits of the track and released it as a Level Kit under Imphenzia Soundtrack. This means that the music is available for non-exclusive licensing at a ridiculously low prices for indie game developers.

The easiest way to check out all the loops and music hits is to visit the Nostalgia Dubstep Level Kit page where you can listen to all the stuff in high quality. You’ll find a full length theme track (4:09 in duration), 7 seamless loops, and 3 music hits. It’s all available individually so you only need to license the ones you want to use – not the entire level kit.

The music is suitable for futuristic games and games with attitude.

• Bitcrusher (Short Loop and Long Loop) is a dirty distorted futuristic beat with attitude.
• Arm For Battle (Loop) is a heroic orchestral loop portraying hope and preparation in a battle scenario.

What else did I do today?

Even though I am on paternity leave things are quite hectic at the moment – but in a good way.  I drop my son off at daycare at 08:45 in the mornings and then I have some time to spare for my projects until 13:30 when I pick him up again. He is only spending short periods of time there still as he just started last week but it’s still a bit heartbreaking leaving him in the morning as he bursts into tears as I leave him. My wife is taking care of our new baby girl most of the time so I can spend the 4 hours on my projects most days. Today was an exception though, I had to spend 2 hours searching for my wallet (which I had apparently left behind at the daycare center) and another 2 hours cleaning my car…. so no time for my projects during the day today.

3DS Max and Unity

I’m also spending some time in 3DS Max learning some low polygon modelling. I am making a little space game so I can learn both 3DS Max and Unity3D properly because I plan to make the sequel to the yet unreleased game “Performa Cars” using Unity’s powerful 3D engine. I will still make the game very much 2D looking because my passion is top-down racing.

Motocross

My KXF 450

Our local motocross track is open on Wednesday evenings (as well as weekends) so today I spend 3 hours there practicing. I rid my Kawasaki KXF 450 (2008 model) and it went fairly well until blisters in my left palm put an end to the session. I’ll have to figure out a way to tape it up for the weekend. My goal is to ride twice a week all year around. In the winter I put on spiked ice tires and I actually prefer to ride in the winter because the grip is amazing… and I don’t overheat as much as I do in the summer =)

Modern Warfare 2

I also managed to squeeze in a two hour session of playing Modern Warfare 2 with a mate of mine tonight.

Plan for the coming weeks

My plan for Imphenzia Projects during the coming weeks include:

• Re-launch the Imphenzia Games web site with the new design (as Music and Soundtrack)
• Release Performa Cars (a.k.a. project Computer Touring Car Championship) as freeware
• Composing more music for release on Imphenzia Soundtrack
• Continue to learn low poly modelling and Unity3D development for future Imphenzia Games projects
• Keep this blog updated

Imphenzia aside, I also need to:

• Spend time with my family
• Practice motocross
• Keep fit (run 3 times a week)
• Buy another car… can’t fit the new double pram in the boot/trunk…
• Contact contractors for building plans… boring…

Now it’s time for bed at 01:53 – should have no problem sleeping.

My library of sound effects currently contains 96 free effects (25 alarm effects, 35 explosions, and 36 laser effects.) You can preview and download all the effects as WAV files (16bit 44.1KHz Stereo), Vorbis OGG files (encoded at the bitrates 128kbps and 64kbps), and MP3 files (encoded at VBR 190kbps.)

To make browsing easier you can click on this link to browse the sound effect library with only the free ones visible =)

Shifting Focus

The first half of this year I put a lot of effort into Imphenzia Music by rebuilding the entire web site from scratch, creating a new web shop, introducing Full Access feature, releasing new singles, releasing the Chillout album, introducing all my music to digital stores and Spotify. I also made the decision to allow full length streaming of ALL my tracks (previously high quality streaming was only allowing the first two minutes.) I’m not sure if that was the right thing to do because since then the number of Full Access users have dropped and now one person every other month opts for (the low end of) Full Access. I will keep things as they are, but I think the lack of interest in downloading my music is one of the reasons why my motivation has switched to Imphenzia Sountrack at the moment. Not to worry, it’ll shift back at some stage =)

There is a hole in my virtual studio

I’ve purchased quite a few great music products over the past few of years, and my current virtual studio consists of the following:

• Steinberg Cubase 5.5
• reFX Nexus2 with the following expansions:
• Psytrance
• Store n Forward
• Hollywood
• Omnicron 2 and 3
• ROM Extension
• reFX VanGuard with the following additional sound banks:
• Bigtone Electronic Garden, Silicon Frontiers Bank and Soundbank
• NextBeat Dance Basics Bank
• Revolution Soundbank 1, 2 and 3
• Synthation Bank
• Toxcity Bank
• Xenox Signature Bank 1 and 2
• LennarDigital Sylenth 1
• EastWest Quantum Leap Symphonic Orchestra Gold (33 GB sample library)
• EastWest Symphonic Choirs (39 GB sample library)
• EastWest Pianos Gold (50 GB sample library)
• Quantum Leap Goliath (41 GB sample library)
• Stormdrum 2 (13 GB sample library)
• Voices of Passion (8 GB sample library)
• Ministry of Rock (20 GB sample library

For Imphenzia Soundtrack, on the other hand, I am missing an instrument or library for soundscape textures, glitches, and futuristic grunge style sounds.

I’ve done some online searching today and I found Native Instruments Abysnth 5 which I think will fill this hole perfectly. Absynth comes with 1800 presets and a, what seems to be an amazing, morph feature that will allow the creation of totally unique sounds. I’ve been looking at the demo videos and listened to the sample tracks and all I have to do now is to decide whether I should by the boxed DVD version or the digital download version. If I get the digital version I’ll have it straight away but I’ve got boxed versions for Nexus, Cubase, and the Complete Composer’s edition (featuring all the large sample libraries) so it would be nice to have the cyan colored Abynth 5 box in that collection. Both the digital download and boxed version is €179 (including shipping) so I’m leaning towards the box after all. My PayPal account is missing $25 so I’ll wait to see if any non-exclusive licenses go so I can place the order.

Good hardware for the gigantic sample libraries

The only music hardware I use nowadays is my 88-key Roland FP-7 stage piano as master midi keyboard and to play improvisation to come up with new ideas. Some will find it amusing, but I use the Asus motherboard sound card. I down-mix all the audio without it ever touching the sound card so it serves no purpose to get another one. In fact, I’ve got a Creamware Pulsar 2 DSP sound card that I bought for £2000 – but it’s old now and they didn’t bother to release any Windows 7 drivers for it… But again, I don’t need it =)

If you found this post because you are looking for a computer with a lot of memory to run the EastWest libraries – I can confirm that my current computer handles it beautifully:

• Asus P6X58D-E Motherboard
• 24 GB RAM using 2 x Corsair 12GB (3 kit) DDR3 1600MHz/CL9/DOMINATOR
• Intel Core i7 3.06GHz Quad 8MB Cache Processor
• Corsair AX 850W PSU
• Crucial RealSSD 256GB (for the sound libraries, they consist of over 177’000 files)
• Corsair SSD Force Series 120GB (for Windows 7 x64 Ultimate

Signing off with a bombshell

To finish off I’ll take this opportunity to share s sample of an orchestral piece I started working on today. Enjoy!
Imphenzia Soundtrack work in progress “Arm for Battle Loop” by Imphenzia

It’s now 1:55 am and I have just finished the task. It wasn’t easy because I spent much of the day with my son (I am on paternity leave) and once he was in bed I watched a movie (True Grit) with my wife.

So what did I accomplish today?

I composed the following short pieces of music (in addition to the loops I composed yesterday):

• Game Over loop
• Menu Music loop
• Boss music loop
• Life Lost music hit
• Get Ready music hit
• Stage Completed music hit

I then down-mixed and mastered all 13 variations where 10 variations are seamless loops that have to be cropped (thank heaven for my seamless loop cropping script =).

Once all the mastered audio files were in place I watermarked the 13 tracks and created OGG and MP3-previews for my site. Then, of course, I encoded the audio files that you get in the license mail which is WAV, OGG 128kbps, OGG 64kbps, and MP3 190kbps versions for each variation. While uploading all the newly encoded files I also entered all the details, keywords, descriptions and meta data about each variation into the database.

All in all I am very pleased with my effort today and to finish it off I also had a few moments to spare to create a news slider for Once Upon a Platform. It uses some graphics from my friend Kenny Lex (thanks mate =)

Once Upon a Platform - News Slider

What next?

I’m truly enjoying making music at the moment and Imphenzia Sountrack allows me to vary the music genres a lot. The other day I was making orchestral battle music, today it was retro styled arcade music, so I’ll flip my 9-sided coin tomorrow and see what the next genre will be. Any requests??

So far I have composed the short, medium, and long stage loops – but during a discussion with a good friend of mine, who listened to the preview of the long loop, he noted that the long loop varied quite a bit in mood – as if it should be split into two separate tracks. My initial intention was to keep the long loop interesting by alternating the music quite a bit, but I have to admit that he was on to something.

When he added (I translate from our chat conversation in Swedish) “In my mind I have just sorted out the first transition in the track… He [the player] just ate a mushroom.”

This spawned the idea. Yes, d@mn it, it’s a classic Super Mario moment and what I’ll do is break out the two loops into separate pieces of music and, since they run at the exact same BPM, encourage the game developer to play them simultaneously during game play (keeping them in sync) and cross-fade between the two to switch the mood.

Dim the lights please…

…and allow me to demonstrate with this simple video:

Before creating the video above, I must admit, I almost bought some stock Flash animations to put together a little demo video of a platform character picking up a power-up. After 2 hours of browsing for suitable animations to buy I gathered my senses and thought – let’s just focus on what I really do – make music instead and just do something “good enough” for a change =)

More about “Once Upon a Platform”

If I’ve kept you reading so far, maybe you are sold on retro game music as well? This morning I launched Cubase with intention to create a set of music hits and loops for cheerful, child friendly, platform games. This meant a simple beat, a nice little base line, retro feel added by some background arpeggios, and a saw lead with portamento (gliding.)

It didn’t take long until I had the beat and bass-line in place and after striking the keys on my Roland FP-7 stage piano for a few minutes I also had a cheerful piano added to the mix. I don’t actually use the sounds from the FP-7 (other than while playing freehand.) Why not, it’s a great sounding instrument? Yes it is – but I just can’t bring myself to have ANY external audio hardware as it would spoil the amazing Audio Mixdown feature in Cubase which just renders the entire song into a WAV file much faster than in real-time.

Passion for retro game music

I use my headphones when I make music, a pair of Sennheiser PXC 450,  so neither my wife nor my son could hear what I was working on. I always get a big smile on my face when I create (or listen to) retro style game music. It’s something about the melody and the sounds, an in combination with my child hood memories that flips the little switch in my head making it impossible to remove the grin. This is when my wife walks into the room. I unplugged the headphones to reveal the source of my smile and let’s just say that she doesn’t share the same passion for this as I do. She is, by the way, pregnant again and she muttered something about that she’d rather give birth, with a long and painful labor, than listen to that ["that" being MY cheerful retro platform music].

Just as quickly as my wife left the room, my 1.5 year old son walks in. Apart from scattering some soil from the large plant onto the floor, something he feels compelled to do every time he walks past it, he walks straight over to me. I lift him up onto my lap and he listened to the full loop, twice, totally mesmerized. He is either frozen in shock (wife DNA) or unable to move in amazement (my DNA.) I choose to believe it’s the latter. It’s all the convincing I need to be sure I should continue and as a result I have now released the preview video.

Why the name?

I initially called my project “Platform Heaven.” As I was out driving in the afternoon I had time to think a bit more about it. I remembered that some of my recent tracks (that hint on what game genre it may be suitable for) have the genre at the end of the track name, not in the front. I should stick to this pattern.

Coincidentally, this morning I also searched the internet for a web shop to buy the DVD box “Il était une fois… l’Espace”, a french cartoon from 1982 that I fell in love with as a kid. The english name for the series is “Once upon a time… Space” and I plan to buy it so I can re-watch it myself and, of course, force feed this amazing series my son. I can’t foresee any problems competing with the super hi-tech 3D animation masterpieces of today.

It goes without saying that I put half and half together = “Once Upon a Platform.” which also reflects the retro aspect to the track. There. I said it anyway.

Equipment and Software used

As usual, I use my trusted Cubase 5.5 as a sequencer and apart from the percussion (which I use the Cubase native Groove Agent One for) it’s all exclusively Nexus2 (by ReFX). I use the original sound banks along with the expansions Omnicron 2 and Omnicron 3. The SID / chip style arpeggios are also Nexus2 leads with arpeggio enabled with a rate of 64th.

This is what my project looks like at the moment (the combined loop of casual and uplifting moods): 

I hope to finish Once Upon a Platform tomorrow and upon completion I will add it to the library of non-exclusive game music.

The idea is to create variations of a track or theme which will cover most stages and situations of a game. Today I have composed and released Battle Zone Level Kit which is an orchestral military style set of music files:

• Get Ready Music Hit (5 seconds) [Play Preview]
• Stage Completed Music Hit (14 seconds) [Play Preview]
• Game Over Loop (23 seconds) [Play Preview]
• Life Lost Music Hit (5 seconds) [Play Preview]
• Menu Loop (15 seconds) [Play Preview]
• Stage Short Loop (16 seconds) [Play Preview]
• Stage Medium Loop (32 seconds) [Play Preview]
• Stage Long Loop (111 seconds) [Play Preview]
• Boss Loop (13 seconds) [Play Preview]

Of course you can license each variation individually and it’s the developers preference whether the Stage Short Loop should really be the Menu loop and so forth, but all the moods are for the various music hits and loops are custom designed to be suitable for the different game stages. As I continue to release Level Kits I hope to offer a very wide selections where you may license all the music necessary for your game.

Battle Zone from a composer’s perspective

If you are interested to find out how the music was composed, read on. I use Cubase 5.5 with my full EastWest Symphonic Orchestra Gold keyswitch template (described in this post) along with Stormdrum 2 percussion, drone sounds from Quantum Leap Goliath, and additional patches from the Hollywood expansion for Nexus2 by ReFX.

Stage / Game Play Loops

The stage loops are fairly static and background like with marching drums, strong percussion, and tense strings and brass. The boss loop which could be used for especially hectic situations and, of course, boss encounters is 20 BPM faster with many french horn rips and violin effects to emphasize the danger.

Music Hits

The Stage Complete Music Hit is more melodic with a positive mood portraying success and accomplishment.

The Game Over Loop is a longer version of the Stage Complete Hit with more melodic and emotional strings and brass to emphasize pride and glory. String ensemble playing in marcato behind the lead instruments in both of these hits also establishes heroic courage.

The Life Lost hit is short with just failure written all over it due to the rips and crecendo strings and horns.

The Menu Loop is a very mysterious soundscape with drones from the Goliath library mentioned above. The same drones can also be found in the long stage loop. Plenty of reverb and a deep bass note playing adds to the tension.

The Get Ready hit is just a simple marching snare with some additional percussion and repeating double bass strings.

You can play the Intense Battle Full Loop to get an appreciation of what it sounds like (Note: the audio file is watermarked if you are wondering why my voice disturbs you gently half way through :)

The loops are very short, only between 10 and 32 seconds in length, making them especially suitable for small games with shorter gameplay. The short duration also makes them incredible cheap with excellent value for money as they are practically given away priced between $3 and $10 each for indie game developers.

Details for the curious

To create these loops I use Steinberg Cubase 5.5 as a sequencer. The orchestral library I use is Symphonic Orchestra Gold by EastWest Samples / Quantum Leap. I’ve set up a, for me, gigantic Cubase template with the full Orchestra and all instruments articulated with keyswitch instruments. The keyswitch means that I can select articulation for each midi note played to say how it should be played, e.g. the keyswitch for 18 Violins section contains no less than 23 articulations such as marcato, sustain, slur, tremolo, legato, lyrical, expressive, quick up down, etc.

Cubase with Symphonic Orchestra Gold Keyswitch template

The orchestral template is very memory hungry and to accomodate this I’m running a Intel i7 950  processor  @3.07 Ghz with 24 GB of RAM memory. I’ve stored all the orchestral library files on a 256 GB Crucial Solid State HDD because the library consists of 39983 files (32.3 GB) and it took forever to load it up on my previous 7200 RPM drive. This is running on Windows 7 x64 Ultimate and I must say that this combination works a treat. I can also take this opportunity to mention that the setup and music software is funded by my every day job as an IT Consultant and NOT from Imphenzia Soundtrack licenses – I’ve got a long way to go for that to happen =)

Here is also a screenshot of the Key Switch articulations I’ve configured. This one is for the 18 Violins sections so I had to configure the same thing for all instruments in the entire orchestra which took me the closest thing to forever.

Key Switch articulations for 18 Violins section

I should also mention that this particular piece of music uses percussion from Stormdrum 2 and a little bit of choir from Symphonic Choirs.